player/player.gd

   1 extends CharacterBody3D
   2 class_name Player
   3
   4
   5 # player settings
   6 @export_group("Movement")
   7 @export var walk_speed := 3.0
   8 @export var jog_speed := 6.0
   9 @export var charge_speed := 20
  10
  11 @export var air_speed := 3.0
  12 @export var acceleration := 20.0
  13 @export var jump_speed := 6.0
  14 @export var rotation_speed := 10.0
  15 @export var fall_speed := 1.2
  16 @export var idle_timeout := 5.0
  17 @export var hard_landing_limit := 10.0
  18
  19 @export_group("Physics")
  20 @export var push_force := 1.5
  21
  22 @export_group("Camera")
  23 @export_range(1.0, 10.0) var camera_distance := 2.5
  24 @export_range(0.0, 1.0) var mouse_sensitivity := 0.15
  25 @export_range(0.0, 1.0) var mouse_sensitivity_x := 1.0
  26 @export_range(0.0, 1.0) var mouse_sensitivity_y := 0.5
  27 @export_range(0.0, 10.0) var joystick_sensitivity_x := 4.0
  28 @export_range(0.0, 10.0) var joystick_sensitivity_y := 2.0
  29
  30
  31 @onready var _debug: CanvasLayer = %debug
  32 @onready var _camera_pivot: Node3D = %camera_pivot
  33 @onready var _camera: Camera3D = %camera
  34 @onready var _skin: AnimatedSkin = %skin
  35
  36 var _last_movement_direction := rotation
  37 var _camera_input_direction := Vector2.ZERO
  38
  39 enum {CAMERA_MOUSE_INPUT, CAMERA_JOYSTICK_INPUT}
  40 var _camera_input_method := CAMERA_MOUSE_INPUT
  41
  42 var _idle_time: float = 0.0
  43 var _player_speed: float = walk_speed
  44
  45
  46 func _ready() -> void:
  47         $camera_pivot/SpringArm3D.spring_length = camera_distance
  48         _debug.draw.add_vector(self, "velocity", 1, 1, Color(0,1,0,1))
  49         _debug.draw.add_vector(self, "_last_movement_direction", 1, 1, Color(1,0,0,1))
  50         _debug.stats.add_property(self, "velocity", "length")
  51         _debug.stats.add_property(self, "_idle_time", "round")
  52
  53
  54 func _physics_process(delta: float) -> void:
  55         _process_camera(delta)
  56         _process_player(delta)
  57
  58
  59 func _unhandled_input(event: InputEvent) -> void:
  60         # If user clicks on the window, capture the mouse and direct the camera with it
  61         if Input.get_mouse_mode() != Input.MOUSE_MODE_CAPTURED:
  62                 return
  63
  64                         #_camera_input_direction *= mouse_sensitivity
  65         if event is InputEventMouseMotion:
  66                 _camera_input_method = CAMERA_MOUSE_INPUT
  67                 _camera_input_direction = event.screen_relative * mouse_sensitivity
  68         elif event is InputEventJoypadMotion:
  69                 _camera_input_method = CAMERA_JOYSTICK_INPUT
  70                 _camera_input_direction = Input.get_vector("camera-left", "camera-right", "camera-up", "camera-down")
  71                 _camera_input_direction *= Vector2(joystick_sensitivity_x, -joystick_sensitivity_y)
  72
  73
  74 func _input(event: InputEvent):
  75         if event.is_action_pressed("player_run"):
  76                 _player_speed = jog_speed
  77         elif event.is_action_released("player_run"):
  78                 _player_speed = walk_speed
  79
  80         if event.is_action_pressed("player_attack") and velocity.length() > jog_speed * .75:
  81                 _player_speed = charge_speed
  82
  83
  84 # Get the XZ input direction based on player's input relative to the camera
  85 func _get_player_move_direction() -> Vector3:
  86         var input_dir := Input.get_vector("player_left", "player_right", "player_forward", "player_backward")
  87         var forward := _camera.global_basis.z
  88         var right := _camera.global_basis.x
  89         var move_direction := (forward * input_dir.y + right * input_dir.x).normalized()
  90         move_direction.y = 0
  91         return move_direction
  92
  93
  94 func _process_camera(delta: float) -> void:
  95         # vertical camera rotation
  96         _camera_pivot.rotation.x += _camera_input_direction.y * mouse_sensitivity_y * delta
  97         _camera_pivot.rotation.x = clamp(_camera_pivot.rotation.x, -PI / 6, PI / 3)
  98
  99         # horizontal camera rotation
 100         _camera_pivot.rotation.y -= _camera_input_direction.x * mouse_sensitivity_x * delta
 101
 102         # reset mouse movement vector if mouse input
 103         if _camera_input_method == CAMERA_MOUSE_INPUT:
 104                 _camera_input_direction = Vector2.ZERO
 105
 106
 107 func _process_player_on_floor(delta: float):
 108         var move_direction := _get_player_move_direction()
 109
 110         # if we're not stuck, then it's okay to set the velocity
 111         velocity = velocity.move_toward(move_direction * _player_speed, acceleration * delta)
 112         var movement_speed := Vector3(velocity.x, 0, velocity.z).length()
 113
 114         # also, if we're moving, we're not idle
 115         if move_direction.length() < 0.2:
 116                 if velocity == Vector3.ZERO:
 117                         _idle_time += delta
 118         else:
 119                 _last_movement_direction = move_direction
 120                 _idle_time = 0.0
 121
 122         # if camera is unlocked, rotate whole skin to face movement direction
 123         # else, rotate to face camera pivot global Y direction
 124         var skin_target_angle := Vector3.BACK.signed_angle_to(_last_movement_direction, Vector3.UP)
 125         _skin.global_rotation.y = lerp_angle(
 126                 _skin.global_rotation.y,
 127                 skin_target_angle,
 128                 rotation_speed * delta
 129                 )
 130         _skin.set_movement_speed(movement_speed)
 131
 132         # timescale tweaking for fun effect!
 133         if movement_speed >= charge_speed * 0.75:
 134                 _skin.set_timescale(2.0)
 135         else:
 136                 _skin.set_timescale(1.0)
 137
 138
 139 func _process_player(delta: float) -> void:
 140         if is_on_floor():
 141                 _process_player_on_floor(delta)
 142         else:
 143                 velocity += get_gravity() * air_speed * delta
 144
 145         # now actually move!
 146         var movement_speed := velocity.length()
 147         move_and_slide()
 148
 149         # handle collisions
 150         for i in get_slide_collision_count():
 151                 var c := get_slide_collision(i)
 152                 if c.get_collider() is RigidBody3D:
 153                         var col: RigidBody3D = c.get_collider()
 154                         col.apply_central_impulse(-c.get_normal() * push_force * movement_speed / col.mass)